Le loader de flash MX connais quelque probleme sous certain navigateur notemment IE. Voici un code à insérer dans une frame pour corriger ce probleme.

actionscript
import mx.controls.Loader;
//define the maxTries here. 
var maxTries:Number = 500;
 
Loader.prototype.checkLoadProgress = function():Void
{
	var i:String;
 
	for (i in this.loadList)
	{
		var x:Object = this.loadList[i];
		//trace("loading..." + loadList[i].url);
 
		x.loaded = x.obj.getBytesLoaded();
		x.total = x.obj.getBytesTotal();
		//trace( x.loaded +"/"+ x.total );
 
		if (x.total > 0)
		{
			x.obj._visible = false;
			this.dispatchEvent({type: "progress", target: x.obj, current: x.loaded, total: x.total});
			if (x.loaded == x.total) {
				if (this.loadedList == undefined)
					this.loadedList = new Object();
				this.loadedList[i] = x;
				delete this.loadList[i];
				this.doLater(this, "contentLoaded");
			}
			else
			{
				//NOTE BGX: also this is different than in the original code where
				//the call to doLater is outside the check "if (x.total > 0)"
				this.doLater(this, "checkLoadProgress");
			}
		}
		else 
		{
			if (x.total == -1)
			{
				// sometimes you get a -1 before it starts loading
				if (x.failedOnce != undefined)
				{
					x.failedOnce++;
					//NOTE BGX: the following is the line changed [orig: if (x.failedOnce > 3)]
					if (x.failedOnce > maxTries)
					{
						this.dispatchEvent({type: "complete", target: x.obj, current: x.loaded, total: x.total});
						//trace("total == -1 loaded = " + x.loaded);
						delete this.loadList[i];
						delete x;
					}
				}
				else
				{
					x.failedOnce = 0;
				}
			}
 
			//NOTE BGX: also this is different than in the original code where
			//the call to doLater is outside the check "if (x.total > 0)"
			this.doLater(this, "checkLoadProgress");
		}
	}
}